Data Export

From glycandata
Jump to: navigation, search

See also the sparql queries and exported data tables in the GlycanDataWiki github repository.

Glycan Properties

PREFIX glycandata: <http://glycandata.glygen.org/glycandata#>

SELECT (?accession AS ?glytoucan_acc)
       (?SubsumptionLevel AS ?glytoucan_type)
       (?UnderivitizedMW AS ?glycan_mass)
       (?PermethylatedMW AS ?glycan_permass)
       (?BaseComposition as ?base_composition)
       (?Composition as ?composition)
       (?Topology as ?topology)
       (?MonosaccharideCount as ?monosaccharides)
WHERE {
  ?glycan glycandata:accession ?accession .
  ?ann0 glycandata:property "GlyGen" .
  ?ann0 glycandata:hasglycan ?glycan
  OPTIONAL {
    ?ann1 glycandata:property "SubsumptionLevel" .
    ?ann1 glycandata:value ?SubsumptionLevel . 
    ?ann1 glycandata:hasglycan ?glycan
  }
  OPTIONAL {
    ?ann2 glycandata:property "UnderivitizedMW" .
    ?ann2 glycandata:value ?UnderivitizedMW . 
    ?ann2 glycandata:source "EdwardsLab" .
    ?ann2 glycandata:hasglycan ?glycan
  }
  OPTIONAL {
    ?ann3 glycandata:property "BaseComposition" .
    ?ann3 glycandata:value ?BaseComposition . 
    ?ann3 glycandata:hasglycan ?glycan
  }
  OPTIONAL {
    ?ann4 glycandata:property "Composition" .
    ?ann4 glycandata:type "Subsumption" .
    ?ann4 glycandata:value ?Composition . 
    ?ann4 glycandata:hasglycan ?glycan
  }
  OPTIONAL {
    ?ann5 glycandata:property "Topology" .
    ?ann5 glycandata:value ?Topology . 
    ?ann5 glycandata:hasglycan ?glycan
  }
  OPTIONAL {
    ?ann6 glycandata:property "MonosaccharideCount" .
    ?ann6 glycandata:value ?MonosaccharideCount . 
    ?ann6 glycandata:source "EdwardsLab" .
    ?ann6 glycandata:hasglycan ?glycan
  }
  OPTIONAL {
    ?ann7 glycandata:property "PermethylatedMW" .
    ?ann7 glycandata:value ?PermethylatedMW . 
    ?ann7 glycandata:hasglycan ?glycan
  }
}

Try Me!

GlycomeDB Cross References

PREFIX glycandata: <http://glycandata.glygen.org/glycandata#>

SELECT (?accession  as ?GlyTouCanAccession)
       (?value as ?GlycomeDBID)
WHERE {
  ?glycan glycandata:accession ?accession .
  ?ann0 glycandata:property "GlyGen" .
  ?ann0 glycandata:hasglycan ?glycan .
  ?ann1 glycandata:property "GlycomeDB" .
  ?ann1 glycandata:value ?value .
  ?ann1 glycandata:hasglycan ?glycan
}

Try Me!

KEGG Cross References

PREFIX glycandata: <http://glycandata.glygen.org/glycandata#>

SELECT (?accession  as ?GlyTouCanAccession)
       (?value as ?KEGGAccession)
WHERE {
  ?glycan glycandata:accession ?accession .
  ?ann0 glycandata:property "GlyGen" .
  ?ann0 glycandata:hasglycan ?glycan .
  ?ann1 glycandata:property "KEGG" .
  ?ann1 glycandata:value ?value .
  ?ann1 glycandata:hasglycan ?glycan
}

Try Me!

UniCarbKB Cross References

PREFIX glycandata: <http://glycandata.glygen.org/glycandata#>

SELECT (?accession  as ?GlyTouCanAccession)
       (?value as ?UniCarbKBID)
WHERE {
  ?glycan glycandata:accession ?accession .
  ?ann0 glycandata:property "GlyGen" .
  ?ann0 glycandata:hasglycan ?glycan .
  ?ann1 glycandata:property "UniCarbKB" .
  ?ann1 glycandata:value ?value .
  ?ann1 glycandata:hasglycan ?glycan
}

Try Me

PubChem Cross References

PREFIX glycandata: <http://glycandata.glygen.org/glycandata#>

SELECT (?accession  as ?GlyTouCanAccession)
       (?value as ?PubChemID)
WHERE {
  ?glycan glycandata:accession ?accession .
  ?ann0 glycandata:property "GlyGen" .
  ?ann0 glycandata:hasglycan ?glycan .
  ?ann1 glycandata:property "PubChem" .
  ?ann1 glycandata:value ?value .
  ?ann1 glycandata:hasglycan ?glycan
}

Try Me

PDB Cross References

PREFIX glycandata: <http://glycandata.glygen.org/glycandata#>

SELECT (?accession  as ?GlyTouCanAccession)
       (?value as ?PDBID)
WHERE {
  ?glycan glycandata:accession ?accession .
  ?ann0 glycandata:property "GlyGen" .
  ?ann0 glycandata:hasglycan ?glycan .
  ?ann1 glycandata:property "PDB" .
  ?ann1 glycandata:value ?value .
  ?ann1 glycandata:hasglycan ?glycan
}

Try Me

Monosaccharide Composition

PREFIX glycandata: <http://glycandata.glygen.org/glycandata#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?accession ?Hex ?HexNAc ?dHex ?NeuAc ?NeuGc ((?Count - ?Hex - ?HexNAc - ?dHex - ?NeuAc - ?NeuGc) as ?Xxx) ?Count
WHERE {
  ?glycan glycandata:accession ?accession .
  ?ann0 glycandata:property "GlyGen" .
  ?ann0 glycandata:hasglycan ?glycan
  OPTIONAL {
    ?ann1 glycandata:property "HexCount" .
    ?ann1 glycandata:value ?HexCount .
    ?ann1 glycandata:hasglycan ?glycan
  }
  OPTIONAL {
    ?ann2 glycandata:property "HexNAcCount" .
    ?ann2 glycandata:value ?HexNAcCount .
    ?ann2 glycandata:hasglycan ?glycan
  }
    OPTIONAL {
    ?ann3 glycandata:property "dHexCount" .
    ?ann3 glycandata:value ?dHexCount .
    ?ann3 glycandata:hasglycan ?glycan
  }  
  OPTIONAL {
    ?ann4 glycandata:property "NeuAcCount" .
    ?ann4 glycandata:value ?NeuAcCount .
    ?ann4 glycandata:hasglycan ?glycan
  }
  OPTIONAL {
    ?ann5 glycandata:property "NeuGcCount" .
    ?ann5 glycandata:value ?NeuGcCount .
    ?ann5 glycandata:hasglycan ?glycan
  }
  ?ann6 glycandata:property "MonosaccharideCount" .
  ?ann6 glycandata:source "EdwardsLab" .
  ?ann6 glycandata:value ?MonoCount .
  ?ann6 glycandata:hasglycan ?glycan
  BIND(xsd:integer(IF(BOUND(?HexCount),?HexCount,0)) as ?Hex)
  BIND(xsd:integer(IF(BOUND(?HexNAcCount),?HexNAcCount,0)) as ?HexNAc)
  BIND(xsd:integer(IF(BOUND(?dHexCount),?dHexCount,0)) as ?dHex)
  BIND(xsd:integer(IF(BOUND(?NeuAcCount),?NeuAcCount,0)) as ?NeuAc)
  BIND(xsd:integer(IF(BOUND(?NeuGcCount),?NeuGcCount,0)) as ?NeuGc)
  BIND(xsd:integer(?MonoCount) as ?Count)
}

Try Me!

Glycan Classification

PREFIX glycandata: <http://glycandata.glygen.org/glycandata#>

SELECT (?accession as ?GlyTouCanAccession) ?Type ?Subtype
WHERE {
  ?glycan glycandata:accession ?accession .
  ?ann0 glycandata:property "GlyGen" .
  ?ann0 glycandata:hasglycan ?glycan .
  ?ann1 glycandata:property "GlycanType" .
  ?ann1 glycandata:value ?Type .
  ?ann1 glycandata:hasglycan ?glycan
  OPTIONAL {
    ?ann2 glycandata:property "GlycanSubtype" .
    ?ann2 glycandata:value ?Subtype .
    ?ann2 glycandata:hasglycan ?glycan
  }
}

Try Me!